blob: 9425a43a3edbb88cc44522bbbbe5a5c714ce2188 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Caltlgin Stsodaat <contact@fossdaily.xyz>
pkgname=python-pytest-md-report
_name="${pkgname#python-}"
pkgver=0.2.0
pkgrel=1
pkgdesc='Pytest plugin to create a report in Markdown table format'
arch=('any')
url='https://github.com/thombashi/pytest-md-report'
license=('MIT')
depends=('python-pytablewriter' 'python-pytest' 'python-tcolorpy' 'python-typepy')
makedepends=('python-setuptools' 'python-build' 'python-install' 'python-wheel')
checkdepends=('python-pytest' 'python-dateutil' 'python-pytz')
source=("$pkgname-$pkgver.tar.gz::https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz"
"$pkgname-$pkgver.tar.gz.asc::https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz.asc")
sha256sums=('c129cebee45f9acb2fc26631ca5845f2d2deabbc134789f163224a347a0f9f5f'
'SKIP')
validpgpkeys=('BCF9203E5E80B5607EAE6FDD98CDA9A5F0BFC367')
build() {
cd "$_name-$pkgver"
python -m build --wheel --skip-dependency-check --no-isolation
}
check() {
cd "$_name-$pkgver"
PYTHONPATH=./ pytest -x tests
}
package() {
export PYTHONHASHSEED=0
cd "$_name-$pkgver"
python -m install --optimize=1 --destdir="$pkgdir/" dist/*.whl
install -Dm644 'README.rst' -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm644 'LICENSE' -t "$pkgdir/usr/share/licenses/$pkgname"
}
# vim: ts=2 sw=2 et:
|