PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>

pkgname=python-pytest-postgresql
_name=${pkgname#python-}
pkgver=5.0.0
pkgrel=2
pkgdesc="Test your code that relies on a running PostgreSQL Database"
arch=(any)
url="https://github.com/ClearcodeHQ/pytest-postgresql"
license=(GPL3)
depends=(
  python-pytest
  python-port-for
  python-mirakuru
  python-setuptools
  python-psycopg
)
makedepends=(
  python-build
  python-installer
  python-wheel
)

source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('dcf4963205d0c81919c59be64b170a3aa707954484dc0dc7aa18b34d3e5b724b')

_archive="$_name-$pkgver"

prepare() {
  cd "$_archive"

  sed -i 's/^addopts.*//' pyproject.toml
}

build() {
  cd "$_archive"

  python -m build --wheel --no-isolation
}

check() {
  cd "$_archive"

  PYTEST_DISABLE_PLUGIN_AUTOLOAD=1 python -m pytest \
    -k "not test_executor_init_with_password"
}

package() {
  cd "$_archive"

  python -m installer --destdir="$pkgdir" dist/*.whl
}