summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c40fd65c016a9aa50c4f047bdb8ff8825d4a04e5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: xiretza <xiretza+aur@xiretza.xyz>

_srcname=pythondata-cpu-mor1kx
pkgname="python-$_srcname-git"
pkgver=2020.08.r3.gff01892
pkgrel=1
pkgdesc="Python module containing verilog files for mor1kx cpu (for use with LiteX)"
arch=(any)
url="https://github.com/litex-hub/pythondata-cpu-mor1kx"
license=('custom:OHDL')
depends=(python)
makedepends=(git python-setuptools)
provides=("${pkgname%%-git}=$pkgver")
conflicts=("${pkgname%%-git}")
source=("git+$url")
sha256sums=('SKIP')

pkgver() {
  cd "$_srcname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$_srcname"
  python setup.py build
}

package() {
  cd "$_srcname"
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build

  install -Dm644 "${_srcname//-/_}/verilog/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set et ts=2 syntax=PKGBUILD: