blob: ac72f5eba6d0b35de8952877d2a57c880450adc0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Butui Hu <hot123tea123@gmail.com>
pkgname=python-pytorch-lightning
_pkgname=pytorch-lightning
pkgver=1.2.8
pkgrel=1
pkgdesc="The lightweight PyTorch wrapper for high-performance AI research"
arch=('any')
url='https://github.com/PyTorchLightning/pytorch-lightning'
license=('Apache')
depends=(
python-fsspec
python-pandas
python-pyaml
python-numpy
python-scikit-learn
python-pytorch
python-torchmetrics
python-torchvision
python-twine
python-tqdm
tensorboard
)
optdepends=(
'python-apex: mixed precision support'
'python-horovod: for distributed training'
)
makedepends=('python-setuptools')
source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/PyTorchLightning/pytorch-lightning/archive/${pkgver}.tar.gz")
sha512sums=('43980e46c7d104409bb97383b7e1858154f00df8950097cb8a4ce444546b1eefa05323a589ed21cbd739cdc95607b94dce3d1ae06bf19e090c6d2641736f0e4b')
get_pyver() {
python -c 'import sys; print(str(sys.version_info[0]) + "." + str(sys.version_info[1]))'
}
build() {
cd "${_pkgname}-${pkgver}"
python setup.py build
}
package() {
cd "${_pkgname}-${pkgver}"
python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
rm -rf "${pkgdir}/usr/lib/python$(get_pyver)/site-packages/tests"
}
# vim:set ts=2 sw=2 et:
|