summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6c92d2a9b38f64adb5a4d066e8e64869d820ee23 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# Maintainer: Colin Unger <mastakata 3 at yahoo dot com>

pkgname=python-pyvex-git
pkgdesc="Python bindings for Valgrind's VEX IR"
url="https://github.com/angr/pyvex"
pkgver=8.19.2.4.r734.050ffe4
pkgrel=1
arch=('any')
depends=('python' 'python-pycparser' 'python-cffi' 'python-archinfo-git' 'python-bitstring' 'python-future')
makedepends=('git' 'make' 'gcc' 'binutils' 'python-setuptools')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
license=('BSD')
source=("$pkgname::git+https://github.com/angr/pyvex.git#branch=master")
md5sums=('SKIP')

pkgver() {
	cd "$srcdir/$pkgname"

	regex='[0-9]\+\.[0-9]\+\.[0-9]\+\.[0-9]\+'
	prefix='ticked version number to'
	rev_num="$(git rev-list --count HEAD)"
	version_no="$(git log -n1 --grep "$prefix $regex" --format=tformat:%s | sed "s/$prefix \($regex\)/\1/g")"
	last_commit="$(git rev-parse --short HEAD)"
	echo "$version_no.r$rev_num.$last_commit"
}

build() {
	cd "$srcdir/$pkgname"
	python setup.py build
}

package() {
	cd "$srcdir/$pkgname"
	python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}