PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer: Maks Verver <maks@verver.ch>
pkgname=python-reader
_name=reader
pkgver=3.16
pkgrel=1
pkgdesc='Python feed reader library for RSS, Atom, and JSON feeds'
arch=(any)
url='https://github.com/lemon24/reader'
license=('BSD-3-Clause')
depends=(
	python-beautifulsoup4
	python-feedparser
	python-iso8601
	python-requests
	python-typing_extensions
	python-werkzeug
)
makedepends=(
	python-build
	python-installer
	python-wheel
)
optdepends=(
	python-flask
	python-humanize
	python-mutagen
	python-requests-wsgi-adapter
)
checkdepends=(
	${optdepends[@]}
	python-lxml
	python-mechanicalsoup
	python-pytest
	python-pytest-subtests
	python-requests-mock
)
source=(
	"$_name-$pkgver.tar.gz::https://github.com/lemon24/$_name/archive/refs/tags/$pkgver.tar.gz"
)
sha256sums=('16ba11ec46cdff10adbbcd04bf7b0b1c749ae6461a169a83f637d10740326a29')

build() {
	cd "$_name-$pkgver"
	python -m build --wheel --no-isolation
}

check() {
	cd "$_name-$pkgver"
	PYTHONPATH=src/ pytest --runslow
}

package() {
	cd "$_name-$pkgver"
	python -m installer --destdir="$pkgdir" dist/*.whl
}