blob: 766a593a9d17d8bd75292c4fc4dacc83ce856e2b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: KokaKiwi <kokakiwi+aur@kokakiwi.net>
_pkgname=result
pkgname="python-$_pkgname"
pkgver=0.13.1
pkgrel=1
pkgdesc="A rust-like result type for Python"
arch=('any')
url="https://pypi.org/project/$_pkgname"
license=('MIT')
depends=('python' 'python-typing_extensions')
makedepends=('python-build' 'python-installer' 'python-wheel' 'python-setuptools')
checkdepends=('python-pytest' 'python-pytest-cov')
source=("$pkgname-$pkgver.tar.gz::https://pypi.org/packages/source/${_pkgname:0:1}/${_pkgname//-/_}/${_pkgname//-/_}-$pkgver.tar.gz")
sha256sums=('8254cef5be1d400bd1df3cb33adf47849ca806c77bf0a45037be47f9496db9be')
b2sums=('e8d13cc162306c9b29b1ae05835864c3e134cb49ab477740ebeeb11af4f39fad3c94b052c9b674c7392df525ff10681dbabac3461dcb37b8af404884af2ba98e')
build() {
cd "${_pkgname//-/_}-${pkgver}"
python -m build --wheel --no-isolation
}
check() {
cd "${_pkgname//-/_}-${pkgver}"
PYTHONPATH="src" pytest
}
package() {
cd "${_pkgname//-/_}-${pkgver}"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|