PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: igo95862 <address at domain dot tld>
pkgname=python-sdbus-git
pkgver=r332.5d18e3c
pkgrel=1
pkgdesc="Modern Python library for D-Bus"
arch=('any')
url="https://github.com/igo95862/python-sdbus"
license=('LGPL-2.1-or-later')
provides=('python-sdbus')
depends=('python' 'systemd-libs')
makedepends=('git' 'python-setuptools' 'gcc')
source=("$pkgname"::"git+https://github.com/igo95862/python-sdbus")
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

check () {
    # TODO: After having a meson build system
    cd "$srcdir/$pkgname"
    local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
    env PYTHONPATH="$PWD/build/lib.linux-$CARCH-${python_version}" python -m unittest --verbose
}

build () {
    cd "$srcdir/$pkgname"
    python setup.py build
}

package() {
    cd "$srcdir/$pkgname"
    python setup.py install --prefix /usr --root "$pkgdir"
}