summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7ce3e0ad6f976a3452c28df51afc7b4a0a3d82da (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
# Contributor: Michal Wojdyla < micwoj9292 at gmail dot com >
# Contributor: Ashley Whetter <(firstname) @ awhetter.co.uk>
_base=seqlearn
pkgname=python-${_base}-git
pkgver=r89.32d4bfa
pkgrel=1
pkgdesc="A sequence classification toolkit for Python"
arch=(any)
url="https://github.com/larsmans/${_base}"
license=('custom')
depends=(python-scipy)
makedepends=(cython python-setuptools git)
source=(git+${url}.git)
sha512sums=('SKIP')

pkgver() {
  cd ${_base}
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd ${_base}
  export PYTHONHASHSEED=0
  python setup.py build_ext --inplace
}

package() {
  cd ${_base}
  PYTHONPYCACHEPREFIX="${PWD}/.cache/cpython/" python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}