PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

# Maintainer: Astro Benzene <universebenzene at sina dot com>
pkgbase=python-spectral-cube
pkgname=('python-spectral-cube' 'python2-spectral-cube' 'python-spectral-cube-doc')
pkgver=0.4.3
pkgrel=1
pkgdesc="Library for reading and analyzing astrophysical spectral data cubes"
arch=('i686' 'x86_64')
url="http://spectral-cube.readthedocs.io/en/latest/"
license=('BSD')
makedepends=('cython' 'cython2' 'python-astropy-helpers>=3.1' 'python2-astropy-helpers' 'python-radio_beam' 'python-sphinx' 'python-sphinx-astropy')
#checkdepends=('python-pytest-astropy' 'python2-pytest' 'python-radio_beam' 'python2-radio_beam')
source=("https://files.pythonhosted.org/packages/source/s/spectral-cube/spectral-cube-${pkgver}.tar.gz")
md5sums=('717815d68f42a9d76ba61d27931712e1')

prepare() {
    cd ${srcdir}/spectral-cube-${pkgver}
    sed -i -e '/auto_use/s/True/False/' setup.cfg

    cp -a ${srcdir}/spectral-cube-${pkgver}{,-py2}
}

build() {
    msg "Building Python2"
    cd ${srcdir}/spectral-cube-${pkgver}-py2
    python2 setup.py build --use-system-libraries --offline

    msg "Building Python3"
    cd ${srcdir}/spectral-cube-${pkgver}
    python setup.py build --use-system-libraries --offline

    msg "Building Docs"
    python setup.py build_docs
}

#check() {
#    cd ${srcdir}/spectral-cube-${pkgver}
#    python setup.py test
#
#    cd ${srcdir}/spectral-cube-${pkgver}-py2
#    python2 setup.py test
#}

package_python2-spectral-cube() {
    depends=('python2>=2.7' 'python2-numpy>=1.8' 'python2-astropy>=1.0' 'python2-radio_beam')
    optdepends=('python2-bottleneck: Speeds up median and percentile operations on cubes with missing data'
                'python-spectral-cube-doc: Documentation for Radio Beam'
                'python-pytest-astropy: For testing')
    cd ${srcdir}/spectral-cube-${pkgver}-py2

    install -D -m644 LICENSE.rst -t "${pkgdir}/usr/share/licenses/${pkgname}"
    install -D -m644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
    python2 setup.py install --root=${pkgdir} --prefix=/usr --optimize=1 --use-system-libraries --offline
}

package_python-spectral-cube() {
    depends=('python' 'python-numpy>=1.8' 'python-astropy>=1.0' 'python-radio_beam')
    optdepends=('python-bottleneck: Speeds up median and percentile operations on cubes with missing data'
                'python-spectral-cube-doc: Documentation for Radio Beam')
    cd ${srcdir}/spectral-cube-${pkgver}

    install -D -m644 LICENSE.rst -t "${pkgdir}/usr/share/licenses/${pkgname}"
    install -D -m644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
    python setup.py install --root=${pkgdir} --prefix=/usr --optimize=1 --use-system-libraries --offline
}

package_python-spectral-cube-doc() {
    pkgdesc="Documentation for Python Radio Beam module"
    cd ${srcdir}/spectral-cube-${pkgver}/docs/_build

    install -d -m755 "${pkgdir}/usr/share/doc/${pkgbase}"
    cp -a html "${pkgdir}/usr/share/doc/${pkgbase}"
}