blob: 8dd69a6e259e3a966c511b7ddee1b3f99a796476 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: piernov <piernov@piernov.org>
pkgname=python-spikingjelly-git
pkgver=r2290.3b8e9acb
pkgrel=1
pkgdesc="Deep learning framework for Spiking Neural Network (SNN) based on PyTorch."
arch=('any')
url="https://github.com/fangwei123456/spikingjelly"
license=('custom')
conflicts=('python-spikingjelly')
provides=('python-spikingjelly')
depends=(
'python-pytorch'
'python-torchvision'
'python-torchaudio'
'tensorboard'
'python-numpy'
'python-scipy'
'python-einops'
'python-tqdm'
'python-matplotlib'
'python-scienceplots'
'python-h5py'
'python-pydantic'
)
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
source=("git+https://github.com/fangwei123456/spikingjelly.git")
md5sums=('SKIP')
pkgver() {
cd "$srcdir"/spikingjelly
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir"/spikingjelly
python -m build --wheel --no-isolation
}
package() {
cd "$srcdir"/spikingjelly
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|