PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Amin Vakil <info AT aminvakil DOT com>

pkgname=python-spotapi
_name=${pkgname#python-}
pkgver=1.2.7
pkgrel=1
pkgdesc="A sleek API wrapper for Spotify's private API"
arch=('any')
url="https://pypi.org/project/spotapi/"
license=('GPL-3.0-only')
depends=(
  'python'
  'python-beautifulsoup4'
  'python-colorama'
  'python-pillow'
  'python-pyotp'
  'python-readerwriterlock'
  'python-requests'
  'python-tls-client'
  'python-typing_extensions'
  'python-validators'
)
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
optdepends=(
  'python-pymongo: pymongo extra'
  'python-redis: redis extra'
  'python-websockets: websocket extra'
)
source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
sha512sums=('132b058a44386109760df57e2b7c1330e79b0bdde69a7c0e608bd0ae0f5870512513108951ab091ea55482e2c77eac0883fe20397618b3c273884742be903520')

build() {
  cd "$_name-$pkgver"
  python -m build --wheel --no-isolation
}

package() {
  cd "$_name-$pkgver"
  python -m installer --destdir="$pkgdir" dist/*.whl
}