blob: 88b4600ce188274c3b0bbdba7bb4da197b64e039 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- sh -*-
pkgname='python-ssort-git'
_pkgname="${pkgname/-git/}"
_srcname="${_pkgname/python-/}"
pkgver=0.13.0.r0.g2025243
pkgrel=1
pkgdesc='Tool for automatically sorting python statements within a module (built from latest commit)'
arch=('any')
url="https://github.com/bwhmather/$_srcname"
license=('MIT') # SPDX-License-Identifier: MIT
makedepends=(
'git'
'python-build'
'python-installer'
'python-wheel'
)
depends=(
'python'
'python-pathspec'
)
source=("git+$url.git")
provides=("$_pkgname")
conflicts=("$_pkgname")
sha256sums=('SKIP')
pkgver() {
cd "$_srcname"
_version=$(git describe --long --tags)
printf 'VERSION = "%s"\n' "${_version%%-*}" > "src/$_srcname/_version.py"
echo "$_version" | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$_srcname/src/$_srcname"
sed -i -E 's/from ssort\.(.+) import/from .\1 import/' *.py
}
build() {
cd "$_srcname"
python -m build --wheel --no-isolation
}
package() {
cd "$_srcname"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm0644 README.rst "$pkgdir/usr/share/doc/$pkgname/README.rst"
}
# eof
|