PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84

# Maintainer: Astro Benzene <universebenzene at sina dot com>

pkgbase=python-stcal
_pyname=${pkgbase#python-}
pkgname=("python-${_pyname}" "python-${_pyname}-doc")
pkgver=1.18.0
pkgrel=1
pkgdesc="STScI tools and algorithms used in calibration pipelines"
arch=('i686' 'x86_64')
url="https://stcal.readthedocs.io"
license=('BSD-3-Clause')
makedepends=('python-setuptools-scm>=3.4'
             'cython>=0.29.21'
             'python-build'
             'python-installer'
             'python-numpy>=2.0.0'
             'python-sphinx-automodapi'
             'python-sphinx_rtd_theme'
             'python-pytest-doctestplus'
             'python-drizzle'
             'python-scikit-image'
             'python-tweakwcs'
             'python-shapely'
             'python-pyarrow'
             'python-astropy-healpix'
             'graphviz')  # wheel required by new setuptools; gwcs, spherical_geometry, stsci.. <- tweakwcs
#checkdepends=('python-pytest'
##             'python-pytest-doctestplus'
#             'python-pytest-timeout'
###            'python-opencv'
#            )   # gwcs(requests <- .. <- scipy), imagestat, spherical_geometry <- tweakwcs drizzle skimage(requests) shapely pyarrow healpix already in makedepends
source=("https://files.pythonhosted.org/packages/source/${_pyname:0:1}/${_pyname}/${_pyname}-${pkgver}.tar.gz")
md5sums=('b41a48356a0aea2e53a8ad8601577fbd')

get_pyver() {
    python -c "import sys; print('$1'.join(map(str, sys.version_info[:2])))"
}

build() {
    cd ${srcdir}/${_pyname}-${pkgver}
    python -m build --wheel --no-isolation #--skip-dependency-check

    msg "Building Docs"
    PYTHONPATH="../build/lib.linux-${CARCH}-cpython-$(get_pyver)" make -C docs html
}

#check() {
#    cd ${srcdir}/${_pyname}-${pkgver}
#    # Cost long time
#    mv src/{,_}${_pyname}
#    PYTHONPATH="build/lib.linux-${CARCH}-cpython-$(get_pyver)" pytest -vv -l -ra --color=yes -o console_output_style=count --timeout 300 \
#        --deselect=tests/test_tweakreg.py::test_get_catalog[GAIADR3_S3-None-2469] #|| warning "Tests failed" # -vv -l -ra --color=yes -o console_output_style=count -p xdist -n 4
#}

package_python-stcal() {
    depends=('python>=3.11'
             'python-drizzle>=2.2.0'
             'python-gwcs>=1.0.1'
             'python-requests>=2.22'
             'python-scipy>=1.14.1'
             'python-scikit-image>=0.21.0'
             'python-tweakwcs>=0.8.8'
             'python-spherical_geometry>=1.3'
             'python-stsci.imagestats>=1.8.3'
             'python-shapely>=2.1.1'
             'python-pyarrow>=10.0.1'
             'python-astropy-healpix>=1.1.2')
    optdepends=('python-stcal-doc: Documentation for stcal')
    cd ${srcdir}/${_pyname}-${pkgver}

    install -D -m644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
    install -D -m644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
    python -m installer --destdir="${pkgdir}" dist/*.whl
}

package_python-stcal-doc() {
    pkgdesc="Documentation for Python STCal"
    arch=('any')
    cd ${srcdir}/${_pyname}-${pkgver}/docs/_build

    install -D -m644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" ../../LICENSE
    install -d -m755 "${pkgdir}/usr/share/doc/${pkgbase}"
    cp -a html "${pkgdir}/usr/share/doc/${pkgbase}"
}