blob: 24577bd92b97c73e3cb79a816fa70105bd6d6652 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Butui Hu <hot123tea123@gmail.com>
# Contributor: Mohammad Hossein Sekhavat <sekhavat17@gmail.com>
_pkgname=streamlit
pkgname=python-streamlit
pkgver=1.12.2
pkgrel=1
pkgdesc='The fastest way to build data apps in Python'
arch=('any')
url='https://streamlit.io'
license=('Apache')
depends=(
python-altair
python-astor
python-attrs
python-base58
python-blinker
python-cachetools
python-click
python-dateutil
python-gitpython
python-numpy
python-packaging
python-pandas
python-pillow
python-protobuf
python-pyarrow
python-pydeck
python-pympler
python-requests
python-toml
python-tornado
python-tzlocal
python-validators
python-watchdog
semver
)
makedepends=(
python-pipenv
python-setuptools
)
source=("${_pkgname}-${pkgver}.tar.gz::https://files.pythonhosted.org/packages/source/${_pkgname::1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"
)
sha512sums=('ce041420550067f284ba23de797e72d3eb6bf9a080b5ee922c1a1ad442bcce0a2c919b4c4fd337ec5e3a1d7b07104bf230019cfc89a8b00375958ac66e2ee863')
build() {
cd "${_pkgname}-${pkgver}"
python setup.py build
}
package() {
cd "${_pkgname}-${pkgver}"
python setup.py install --root="${pkgdir}" --optimize=0 --skip-build
rm -vf "${pkgdir}/usr/bin/streamlit.cmd"
}
# vim:set ts=2 sw=2 et:
|