PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer:
# Contributor: Daniel Scheiermann  <daniel.scheiermann@stud.uni-hannover.de>

## useful links:
# https://pypi.org/project/supersolids
# https://github.com/Scheiermann/supersolids

_module="supersolids"
_pkgname="python-$_module"
pkgname="$_pkgname"
pkgver=0.1.33
pkgrel=2
pkgdesc="Simulate and animate supersolids by solving the Schrödinger equation"
url="https://pypi.org/project/supersolids"
license=("MIT")
arch=(any)

depends=('python')
makedepends=(
  'python-build'
  'python-installer'
  'python-setuptools'
  'python-wheel'
)

_pkgsrc="$_module-$pkgver"
_pkgext="tar.gz"
source=("$_pkgsrc.$_pkgext"::"https://files.pythonhosted.org/packages/source/${_module::1}/$_module/$_pkgsrc.$_pkgext")
sha256sums=('01d7068678a577fcf6b8b4a5785a00333128ad22d9e4596c3dd3c1eba7103e7e')

build() {
  cd "$_pkgsrc"
  python -m build --wheel --no-isolation
}

package() {
  depends+=(
    'python-dill'
    'python-matplotlib'
    'python-numpy'
    'python-psutil'
    'python-ffmpeg-python'
    'python-scipy'
    'vtk'

    # AUR
    'python-mayavi'
      # python-envisage
  )

  cd "$_pkgsrc"
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm644 LICENSE.rst "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}