PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Sergey Astanin s<dot>astanin<at>gmail<dot>com
# Contributor: Mikhail felixoid Shiryaev mr<dot>felixoid<at>gmail<dot>com

_name=tabulate
pkgdesc='Pretty-print tabular data in Python, a library and a command-line utility.'
url="https://github.com/astanin/python-${_name}"
pkgname="python-${_name}-git"
pkgver=0.9.0.r29.95ae5eb
pkgrel=1
arch=('any')
makedepends=(python-build python-installer python-wheel)
license=('MIT')
source=("${_name}::git+${url}.git")
provides=( "python-${_name}" )
conflicts=( "python-${_name}" )
sha1sums=('SKIP')

pkgver() {
	cd "${_name}"
	( set -o pipefail
		git describe --long --tags 2>/dev/null | sed 's/\([^-]*-\)g/r\1/;s/-/./g;s/^v//' ||
		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	)
}

build() {
	cd "${_name}"
	python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
	cd "${srcdir}/${_name}"
	PYTHONPYCACHEPREFIX="${PWD}/.cache/cpython/" python -m installer --destdir="${pkgdir}" dist/*.whl
	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/"LICENSE
}