PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Maximilian Stahlberg <maximilian.stahlberg tu-berlin de>
# Contributor: Feufochmar <feufochmar dot gd at gmail dot com>

pkgname=python-tcod
pkgver=13.0.0
pkgrel=1
pkgdesc='High-performance Python port of libtcod'
arch=('x86_64')
url='https://github.com/libtcod/python-tcod'
license=('BSD')
depends=(
	'python-cffi'
	'python-numpy>=1.20.3'
	'python-typing_extensions')
makedepends=(
	'git'
	'python-setuptools'
	'python-pytest-runner'
	'python-pycparser>=2.14'
	'python-sphinx'
	'sdl2>=2.0.5')
source=("$pkgname-$pkgver::git+$url#tag=$pkgver?signed"
        'libtcod::git+https://github.com/libtcod/libtcod#tag=1.18.1?signed')
sha256sums=('SKIP'
            'SKIP')
validpgpkeys=('9EF1E80F3817BC043097A7C15814977902B194CC') # Kyle Benesch @ GitHub

prepare() {
	cd "$pkgname-$pkgver"
	git submodule init
	git config submodule.libtcod.url "$srcdir/libtcod"
	git submodule update
}

build() {
	cd "$pkgname-$pkgver"
	python setup.py build
	cd docs
	make man
}

# check() {
# 	cd "$pkgname-$pkgver"
# 	local _ver="$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')"
# 	PYTHONPATH="$PWD/build/lib.linux-$CARCH-$_ver" python setup.py pytest
# }

package() {
	cd "$pkgname-$pkgver"
	PYTHONHASHSEED=0 python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
	install -Dm 644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
	install -Dm 644 docs/_build/man/python-tcod.1 -t "$pkgdir/usr/share/man/man1/"
}