PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Philip Goto <philip.goto@gmail.com>
# Contributor: DanManN <dnahimov@gmail.com>

pkgname=python-thinc-git
pkgver=8.0.6.r0.g2cdd3d28
pkgrel=1
pkgdesc='Practical Machine Learning for NLP'
arch=(x86_64 aarch64)
url='https://github.com/explosion/thinc'
license=(MIT)
depends=(
	python-blis
	python-catalogue
	python-cymem
	python-hypothesis
	python-mock
	python-murmurhash
	python-numpy
	python-pathlib
	python-plac
	python-preshed
	python-pydantic
	python-six
	python-srsly
	python-tqdm
	python-wasabi
)
makedepends=(
	git
	python-setuptools
	cython
)
provides=(python-thinc)
conflicts=(python-thinc)
source=("git+https://github.com/explosion/thinc.git")
sha256sums=('SKIP')

pkgver() {
	cd thinc
	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	cd thinc
	python setup.py build
}

package() {
	cd thinc
	python setup.py install --skip-build --root="${pkgdir}" --optimize=1
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"    
}