blob: 0a8ca880341cad644e73e48b7724cf341aa968f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
_base=trame-components
pkgname=python-${_base}
pkgdesc="Core components for trame widgets"
pkgver=2.3.2
pkgrel=1
arch=(any)
url="https://github.com/Kitware/${_base}"
license=(Apache-2.0)
depends=(python-trame-client)
makedepends=(python-build python-installer python-setuptools python-wheel nodejs npm)
checkdepends=(python-pytest)
source=(${_base}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz)
sha512sums=('21a65f7f8568e46495a3ae44fc38639998caf3a59b76c6e9511d02e85ee6a2c71c145b37c29f3a09f0b05698c1c8227594dc61568b4a7136b7ac9282ae5eacbf')
prepare() {
sed -i 's/^include/#include/' ${_base}-${pkgver}/MANIFEST.in
}
build() {
cd ${srcdir}/${_base}-${pkgver}/vue-components
npm install
npm run build
cd ${srcdir}/${_base}-${pkgver}
python -m build --wheel --skip-dependency-check --no-isolation
}
check() {
cd ${_base}-${pkgver}
python -m venv --system-site-packages test-env
test-env/bin/python -m installer dist/*.whl
test-env/bin/python -m pytest
}
package() {
cd ${_base}-${pkgver}
PYTHONPYCACHEPREFIX="${PWD}/.cache/cpython/" python -m installer --destdir="${pkgdir}" dist/*.whl
install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
rm ${pkgdir}${site_packages}/trame/__init__.py
rm ${pkgdir}${site_packages}/trame/modules/__init__.py
rm ${pkgdir}${site_packages}/trame/widgets/__init__.py
}
|