blob: 81293191fdf7a1bd9a5a953e5bf1367627c7f5ba (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Daniel Bershatsky <bepshatsky@yandex.ru>
# Contributor: Filip Graliński <filipg@amu.edu.pl>
pkgname=python-transformers
_pkgname=${pkgname#python-}
pkgver=5.12.1
pkgrel=1
pkgdesc='State-of-the-art pretrained models for inference and training'
arch=('any')
url='https://github.com/huggingface/transformers'
license=('Apache-2.0')
depends=(
'python-huggingface-hub>=1:1.3.0'
'python-numpy'
'python-packaging'
'python-regex'
'python-safetensors'
'python-tokenizers'
'python-tqdm'
'python-typer'
'python-yaml'
)
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
optdepends=(
'python-bitsandbytes: 8-bit support for PyTorch'
'python-flax: JAX support'
'python-keras: Support for models in Keras 3'
'python-onnxconverter-common: TensorFlow support'
'python-pytorch: PyTorch support'
'python-tensorflow: TensorFlow support'
'python-tf-keras: Support for models in Keras 2 (e.g. BART)'
'python-tf2onnx: TensorFlow support'
'python-hf-xet: xethub support'
)
source=(
"python-transformers-$pkgver.tar.gz"::"https://github.com/huggingface/transformers/archive/refs/tags/v$pkgver.tar.gz"
)
sha256sums=('c27e47bc2edd859d72c8fdc3fd464b5eb9c8bf4a9756192a9b5ebe496fd5bf9f')
prepare() {
cd "transformers-$pkgver"
# Remove annoying dependency check on `tokenizers`.
sed -i '/tokenizers/c\ "tokenizers": "tokenizers",' \
src/transformers/dependency_versions_table.py
}
build() {
python -m build -nw "transformers-$pkgver"
}
check() {
cd "transformers-$pkgver"
PYTHONPATH=$PWD/src python -c 'import transformers'
}
package() {
cd "transformers-$pkgver"
install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
python -m installer --compile-bytecode=1 --destdir=$pkgdir \
$srcdir/$_pkgname-$pkgver/dist/transformers-$pkgver-*-*.whl
}
|