PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer: RubenKelevra <rubenkelevra@gmail.com>
# Contributor: Rafael Dominiquini <rafaeldominiquini at gmail dot com>

pkgname=python-tree-sitter-cpp
_gitpkgname=tree-sitter-cpp
pkgver=0.23.4
pkgrel=2
pkgdesc='Python Bindings for tree-sitter-cpp'
arch=(
      'x86_64'
      'aarch64'
)
url='https://github.com/tree-sitter/tree-sitter-cpp'
license=('MIT')
depends=(
	'python'
	"tree-sitter-cpp=${pkgver}"
	'python-tree-sitter'
	'tree-sitter'
)
makedepends=(
	'python-build'
	'python-installer'
	'python-setuptools'
	'python-wheel'
)

source=(
	"${_gitpkgname}-${pkgver}.tar.xz::${url}/releases/download/v${pkgver}/${_gitpkgname}.tar.xz"
)

# tar is slightly broken with weird hardlinks, so we need to handle this manually
noextract=(
	"${_gitpkgname}-${pkgver}.tar.xz"
)

b2sums=('409f866165e81845ace0e59e388477b254de3b2d099370d7a0d580adaa7de889d8d55915caff35102be33e174dae40ac56815190cbf300f8128d7d51fe0ed7e5')

prepare() {
	rm -rf "${srcdir}/${_gitpkgname}-${pkgver}"
	mkdir -p "${srcdir}/${_gitpkgname}-${pkgver}"
	tar -xJf "${srcdir}/${_gitpkgname}-${pkgver}.tar.xz" -C "${srcdir}/${_gitpkgname}-${pkgver}"
}

build() {
	cd "${srcdir}/${_gitpkgname}-${pkgver}"
	python -m build --wheel --no-isolation
}

package() {
	cd "${srcdir}/${_gitpkgname}-${pkgver}"
	python -I -m installer --destdir="${pkgdir}" --compile-bytecode 2 dist/*.whl
	install -D -m 644 -t "${pkgdir}/usr/share/doc/${pkgname}" README.md
	install -D -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
}