blob: ee17ca8916098206f338d5fc6b5576a6008a6cdb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: Brad Pitcher <bradpitcher@gmail.com>
# Contributor: Jelle van der Waa <jelle@archlinux.org>
_base=trimesh
pkgname=python-${_base}
pkgver=3.22.1
pkgrel=1
pkgdesc="Import, export, process, analyze and view triangular meshes"
arch=(any)
url="https://${_base}.org"
license=(MIT)
depends=(python python-numpy)
makedepends=(python-build python-installer python-setuptools python-wheel)
checkdepends=(python-pytest python-scipy python-lxml python-rtree python-networkx
python-jsonschema python-pillow python-requests python-shapely python-pyinstrument
python-collada python-svg.path python-mapbox-earcut) # python-sympy python-msgpack python-pyglet openscad
optdepends=('python-scipy: convex hulls'
'python-lxml: handle XML better and faster than built- in XML'
'python-networkx: graph operations'
'python-shapely: vector path handling'
'python-rtree: vector path handling'
'python-requests: network requests'
'python-sympy: do analytical math'
'python-xxhash: hash ndarrays faster than built-in MD5/CRC'
'python-msgpack: serialize into msgpack'
'python-chardet: encoding'
'python-colorlog: print logs with colors'
'python-pillow: load images'
'python-svg.path: handle SVG format path strings'
'python-jsonschema: validate JSON schemas like GLTF'
'python-collada: parse collada/dae/zae files'
'python-pyglet: preview windows'
'python-meshio: load mesh formats'
'python-scikit-image: for voxel ops'
'python-mapbox-earcut: triangulate polygons'
'python-psutil: get memory usage'
'python-ruff: static code analyzer'
'autopep8: code formatter'
'python-pytest: test runner'
'python-pyinstrument: sampling based profiler') # python-xatlas python-fcl python-glooey
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/mikedh/${_base}/archive/${pkgver}.tar.gz)
sha512sums=('27952e0d29ccd110d4087b4144e0923706bed3cd0734e7a17d7f55738c6322849c5dad04ab4ecfe0638bc16d65d1e647d08905a396dd6ebd1f78c833a8b95636')
build() {
cd ${_base}-${pkgver}
python -m build --wheel --skip-dependency-check --no-isolation
}
check() {
cd ${_base}-${pkgver}
python -m venv --system-site-packages test-env
test-env/bin/python -m installer dist/*.whl
test-env/bin/python -m pytest
}
package() {
cd ${_base}-${pkgver}
PYTHONPYCACHEPREFIX="${PWD}/.cache/cpython/" python -m installer --destdir="${pkgdir}" dist/*.whl
install -D -m644 LICENSE.md "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}
|