blob: bffbe77765f15c0f04af29953e4fb86aacd4e7b9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Guillaume Horel <guillaume.horel@gmail.com>
# Maintainer: Caleb Maclennan <caleb@alerque.com>
pkgname=python-ufonormalizer
_pyname=${pkgname#python-}
pkgver=0.6.1
pkgrel=4
pkgdesc='A tool that will normalize XML and other data inside of a UFO'
arch=(any)
url="https://github.com/unified-font-object/ufoNormalizer"
license=(BSD-3-Clause)
depends=(python)
makedepends=(python-{build,installer,wheel}
python-setuptools-scm)
checkdepends=(python-pytest)
_archive="$_pyname-$pkgver"
source=("https://files.pythonhosted.org/packages/source/${_pyname::1}/$_pyname/$_archive.zip")
sha256sums=('e61110e75a500083f265385b1354b578610f9542e3bbbeedb98a2a6155e4aa6c')
prepare() {
cd "$_archive"
# Upstream Issue: https://github.com/unified-font-object/ufoNormalizer/issues/87
sed -i -e 's/ "wheel",//' pyproject.toml
}
build() {
cd "$_archive"
python -m build -wn
}
check() {
cd "$_archive"
export PYTHONPATH="$PWD/build/lib"
pytest
}
package() {
cd "$_archive"
python -m installer -d "$pkgdir" dist/*.whl
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE.txt
}
|