PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28

# Maintainer: begin-theadventure <begin-thecontact.ncncb at dralias dot com>
# Contributor: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Andrea Orru <andrea at orru dot io>
# Contributor: Andrew Rabert <ar at nullsum dot net>

pkgname=python-undervolt
_pkg="${pkgname#python-}"
pkgver=0.3.0
pkgrel=3
pkgdesc="Undervolt Intel CPUs under Linux"
arch=('any')
url="https://github.com/georgewhewell/undervolt"
license=('GPL')
depends=('python')
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
conflicts=('undervolt')
source=("$pkgname-$pkgver.tar.gz::https://files.pythonhosted.org/packages/source/u/$_pkg/$_pkg-$pkgver.tar.gz")
sha256sums=('ae8d49526ecb68acc15faac860404f6692208b540a0b33781d96396cac862767')

build() {
	cd "$_pkg-$pkgver"
	python -m build --wheel --no-isolation
}

package() {
	cd "$_pkg-$pkgver"
	PYTHONHASHSEED=0 python -m installer --destdir="$pkgdir" dist/*.whl
}