blob: b6eae821ff494ddd9aadd28d7ffb420333f1c278 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
|
# Maintainer: Sherlock Holo <sherlockya@gmail.com>
pkgname=python-uvloop-systemlibuv
_pkgname=uvloop
pkgver=0.8.1
pkgrel=2
pkgdesc="A fast, drop-in replacement of the built-in asyncio event loop. Use system libuv."
url="https://github.com/MagicStack/uvloop"
provides=('python-uvloop')
license=('MIT' 'APACHE')
arch=('i686' 'x86_64')
depends=('python' 'libuv')
makedepends=('cython' 'python-setuptools')
conflicts=('python-uvloop')
source=("https://github.com/MagicStack/$_pkgname/archive/v$pkgver.tar.gz")
sha256sums=('5757dce1d8185ead294f2e5b8ad04b343c100fe61863bfbd5994725e86a6a49c')
build() {
cd "$srcdir"/$_pkgname-$pkgver
rm -rf vendor
python setup.py build_ext --inplace --use-system-libuv
python setup.py build_py
}
package() {
cd "$srcdir"/$_pkgname-$pkgver
python setup.py install --skip-build --root="$pkgdir/" --optimize=1
install -m0644 -D LICENSE-MIT "$pkgdir"/usr/share/licenses/$pkgname/LICENSE-MIT
install -m0644 -D LICENSE-APACHE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE-APACHE
}
|