blob: 51aa2a95f9dd9c4d5132211ed49d4e161ba34131 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: DanielNak <daniel@tee.cat>
# Python package author: Kevin McCarthy <me@kevinmccarthy.org>
pkgname=python-vcrpy-git
_pkgname="${pkgname#python-}"
_pkgname="${_pkgname%-git}"
_author=kevin1024
pkgver=8.3.0.r0.gc599974
pkgrel=1
pkgdesc="Simplify and speed up tests that make HTTP requests"
arch=('any')
url="https://github.com/$_author/$_pkgname"
license=('MIT')
depends=('python' 'python-pyyaml' 'python-wrapt')
makedepends=('git' 'python-build' 'python-installer' 'python-setuptools')
checkdepends=(
'python-aiohttp'
'python-boto3'
'python-httpx'
'python-pytest'
'python-pytest-aiohttp'
'python-pytest-asyncio'
'python-pytest-httpbin'
'python-requests'
'python-tornado'
)
provides=("python-$_pkgname=$pkgver")
conflicts=("python-$_pkgname")
source=("git+https://github.com/$_author/$_pkgname.git")
sha256sums=('SKIP')
pkgver() {
cd "$_pkgname"
git describe --tags --long | sed 's/^[^0-9]*//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$_pkgname"
python -m build --wheel --no-isolation
}
check() {
cd "$_pkgname"
python -m pytest \
--ignore tests/integration \
-m 'not online' \
-W ignore::DeprecationWarning
}
package() {
cd "$_pkgname"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE* -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|