blob: 44641755edd87861c77702b1d6670b4bd3674b40 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Mikkel Oscar Lyderik <m at moscar dot net>
_py=python
_gitname=python
pkgname=${_py}-vlc-git
pkgver=r299.f181106
pkgrel=1
pkgdesc="Python bindings for VLC"
arch=('any')
url="https://wiki.videolan.org/Python_bindings"
license=('GPLv2')
depends=(${_py} 'vlc')
makedepends=("${_py}-distribute" "git")
provides=('python-vlc')
conflicts=('python-vlc')
source=("git://git.videolan.org/vlc/bindings/${_gitname}.git"
'setup.py')
sha1sums=('SKIP'
'd5aa28f55600795e71a9a28e0d633d20ad2cc0ee')
pkgver() {
cd "${srcdir}/${_gitname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
# use custom setup.py
cp setup.py "${srcdir}/${_gitname}/"
# move vlc.py to root
cp "${srcdir}/${_gitname}/generated/3.0/vlc.py" "${srcdir}/${_gitname}/"
}
build() {
cd "${srcdir}/${_gitname}"
# build module
${_py} setup.py build
}
package() {
cd "${srcdir}/${_gitname}"
${_py} setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
}
# vim:set ts=2 sw=2 et:
|