summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1d60a83a53a6ecc1ccffd26d0b57a96f286ab3c3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# Maintainer: xiretza <xiretza+aur@xiretza.xyz>

_pkgname=vtr-xml-utils
pkgname="python-$_pkgname-git"
pkgver=r86.d6ba1f1
pkgrel=1
pkgdesc="Utilities for working with VtR XML Files"
arch=(any)
url="https://github.com/SymbiFlow/vtr-xml-utils"
license=('ISC')
depends=('python' 'python-lxml')
makedepends=('git' 'python-setuptools')
checkdepends=('python-pytest')
provides=("${pkgname%%-git}")
conflicts=("${pkgname%%-git}")
source=("git+$url.git")
sha256sums=('SKIP')

pkgver() {
	cd "$_pkgname"

	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$_pkgname"

	python setup.py build
}

check() {
	cd "$_pkgname"

	touch tests/__init__.py
	pytest
}

package() {
	cd "$_pkgname"

	python setup.py install --root="$pkgdir" --optimize=1 --skip-build

	install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}