summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: fb77e48a20e1da84ece8a4842215dedb75d479a2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
# Maintainer: Florijan Hamzic <florijanh at gmail dot com>
# Maintainer: Caleb Maclennan <caleb@alerque.com>

_pypi_name=WeasyPrint
pkgname=python-${_pypi_name,,}
pkgver=52.5
pkgrel=4
pkgdesc='Convert web documents (HTML, CSS, SVG, ...) to PDF'
license=('BSD')
arch=('any')
url='http://weasyprint.org'
_py_deps=(cairo cairocffi cairosvg cffi cssselect2 html5lib pillow pyphen tinycss2)
depends=(python "${_py_deps[@]/#/python-}")
makedepends=(python-pytest-runner python-setuptools)
source=("https://files.pythonhosted.org/packages/source/${_pypi_name::1}/$_pypi_name/$_pypi_name-$pkgver.tar.gz")
sha256sums=('b37ea02d75ca04babd7becad7341426be332ae560d8f02d664bfa1e9afb18481')

build() {
    cd "$_pypi_name-$pkgver"
    python setup.py build
}

package() {
    cd "$_pypi_name-$pkgver"
    python setup.py install --root="$pkgdir" --optimize=1 --skip-build
}