blob: ca2531e5f0f5a1a7a54b447900ae4b5b48e652de (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: Astro Benzene <universebenzene at sina dot com>
pkgbase=python-xarray-datatree
_pyname=${pkgbase#python-}
pkgname=("python-${_pyname}" "python-${_pyname}-doc")
pkgver=0.0.13
pkgrel=1
pkgdesc="Hierarchical tree-like data structures for xarray"
arch=('any')
url="https://xarray-datatree.readthedocs.io"
license=('Apache')
makedepends=('python-setuptools-scm'
'python-wheel'
'python-build'
'python-installer'
'check-manifest'
'python-sphinx-autosummary-accessors'
'python-sphinx-copybutton'
'python-sphinx-book-theme'
'python-sphinxcontrib-srclinks'
'python-sphinxext-opengraph'
'python-nbsphinx'
'python-numpydoc'
'ipython'
'python-xarray'
'ttf-roboto')
checkdepends=('python-pytest'
'python-netcdf4'
'python-h5netcdf'
'python-zarr') # xarray already in makedepends
source=("https://files.pythonhosted.org/packages/source/${_pyname:0:1}/${_pyname}/${_pyname}-${pkgver}.tar.gz")
md5sums=('2a76392d0d015ce590624c3c4672267c')
prepare() {
cd ${srcdir}/${_pyname}-${pkgver}
mkdir -p docs/source/_static
sed -i -e "/GH/s/GH/GH\%s/" docs/source/conf.py
}
build() {
cd ${srcdir}/${_pyname}-${pkgver}
python -m build --wheel --no-isolation
msg "Building Docs"
PYTHONPATH="../build/lib" make -C docs html
}
check() {
cd ${srcdir}/${_pyname}-${pkgver}
# E ModuleNotFoundError: No module named 'xarray.tests'
pytest --ignore=datatree/tests/test_datatree.py || warning "Tests failed" # -vv -l -ra --color=yes -o console_output_style=count
}
package_python-xarray-datatree() {
depends=('python>=3.9' 'python-xarray>=2022.6.0' 'python-packaging')
optdepends=('python-netcdf4: allow file I/O'
'python-h5netcdf: allow file I/O'
'python-zarr: allow file I/O'
'python-xarray-datatree-doc: Documentation for xarray datatree')
cd ${srcdir}/${_pyname}-${pkgver}
install -D -m644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -D -m644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
python -m installer --destdir="${pkgdir}" dist/*.whl
}
package_python-xarray-datatree-doc() {
pkgdesc="Documentation for xarray datatree"
cd ${srcdir}/${_pyname}-${pkgver}/docs/_build
install -D -m644 ../../LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -d -m755 "${pkgdir}/usr/share/doc/${pkgbase}"
cp -a html "${pkgdir}/usr/share/doc/${pkgbase}"
}
|