blob: 824d939055df11db418b5a9d1fe735a07d92200f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>
# Contributor: András Wacha <awacha@gmail.com>
# Contributor: Michał Wojdyła < micwoj9292 at gmail dot com >
pkgname=python-xhtml2pdf
_pkgname=${pkgname#python-}
pkgver=0.2.15
pkgrel=2
pkgdesc="A library for converting HTML into PDFs using ReportLab"
arch=(any)
url="https://github.com/xhtml2pdf/xhtml2pdf"
license=(Apache-2.0)
depends=(
python
python-arabic-reshaper
python-asn1crypto
python-bidi
python-html5lib
python-pillow
python-pyhanko
python-pyhanko-certvalidator
python-pypdf
python-reportlab
python-svglib
python-typing_extensions
)
makedepends=(
python-build
python-installer
python-setuptools
python-wheel
# Documentation
python-sphinx_rtd_theme
python-sphinxcontrib-pdfembed
texlive-fontsextra
texlive-latexextra
)
checkdepends=(python-nose)
source=(
"$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz"
"reportlab-4.1.0-compatibility.patch"
)
sha256sums=(
'4e802908267d3b8682076cca11cb314997dff946400e10a929243d40b4c17e28'
'53fb653376a3d92cf50d28094c99e6685a588ab9390526e31992815690ea9096'
)
_archive="$_pkgname-$pkgver"
prepare() {
cd "$_archive"
patch --forward --strip=1 --input="$srcdir/reportlab-4.1.0-compatibility.patch"
}
build() {
cd "$_archive"
python -m build --wheel --no-isolation
export PYTHONPATH=$PWD/docs/source:$PWD
make -C docs html man
}
check() {
cd "$_archive"
nosetests
}
package() {
cd "$_archive"
python -m installer --destdir="$pkgdir" dist/*.whl
install -dm755 "$pkgdir/usr/share/doc/$pkgname"
cp -at "$pkgdir/usr/share/doc/$pkgname" docs/build/html
install -Dm644 -t "$pkgdir/usr/share/man/man1" docs/build/man/xhtml2pdf.1
}
|