blob: 9476c0f34150b67a977413a5fb4a6b1e92eaf28c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Astro Benzene <universebenzene at sina dot com>
pkgbase=python2-corner
pkgname=('python2-corner' 'python2-corner-doc')
pkgver=2.0.0
pkgrel=1
pkgdesc="Make some beautiful corner plots of samples"
arch=('any')
url="http://corner.readthedocs.io/en/latest/"
license=('BSD')
makedepends=('python2-setuptools' 'python2-matplotlib' 'python2-sphinx' 'python2-sphinx_rtd_theme')
checkdepends=('python2-pytest' 'python2-pandas' 'python2-nose')
source=("https://github.com/dfm/corner.py/archive/v${pkgver}.tar.gz"
'corner-doc.patch')
md5sums=('249abecbc22e73549b46946b0219791f'
'46fb1c445af9d46fa1481054f5178c03')
prepare() {
cd ${srcdir}/corner.py-${pkgver}
patch -Np1 -i "${srcdir}/corner-doc.patch"
}
build () {
cd ${srcdir}/corner.py-${pkgver}
python2 setup.py build
msg "Building Docs"
cd ${srcdir}/corner.py-${pkgver}/docs
make SPHINXBUILD=sphinx-build2 html
}
check(){
cd ${srcdir}/corner.py-${pkgver}
python2 setup.py test
}
package_python2-corner() {
depends=('python2' 'python2-matplotlib')
optdepends=('python2-corner-doc: Documentation for corner.py')
cd ${srcdir}/corner.py-${pkgver}
install -D -m644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -D -m644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
python2 setup.py install --root=${pkgdir} --prefix=/usr --optimize=1
}
package_python2-corner-doc() {
pkgdesc="Documentation for corner.py"
cd ${srcdir}/corner.py-${pkgver}/docs/_build
install -d -m755 "${pkgdir}/usr/share/doc/python2-corner"
cp -a html "${pkgdir}/usr/share/doc/python2-corner"
}
|