PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Jonathan Kohler <kohler.jonathan@gmail.com>
pkgname=python2-labrad-git
pkgver() {
	cd "$srcdir/${pkgname}"
	# Git, tags available
	printf "%s" "$(git describe --long --tags | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g')"
}
pkgver=0.97.2.r3.e9bb3e6
pkgrel=1
pkgdesc="LabRAD is a system for quickly and easily building distributed instrument control and data analysis applications. pylabrad provides a python interface to LabRAD."
arch=("any")
url="https://github.com/labrad/pylabrad"
license=('GPL2')
depends=(
	'python2>=2.7'
	'python2-future'
	'python2-numpy>=1.9.1'
	'python2-configparser'
	'python2-futures>=3.0.4'
	'python2-pyopenssl>=0.13'
	'python2-pyparsing>=2.1.0'
	'python2-requests'
	'python2-service-identity'
	'python2-twisted>=16.0'
)
makedepends=("git")
optdepends=()
source=("$pkgname::git+https://github.com/labrad/pylabrad.git")
md5sums=('SKIP')

build() {
    cd "$srcdir/$pkgname"
    python2 setup.py build
}

package() {
    cd "$srcdir/$pkgname"
    python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1 --skip-build
    install -D -m644 labrad/LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}