blob: 79d33cf8ecbb2b0edf1629885cb03f0a80a1ccf4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Karol "Kenji Takahashi" Woźniak <kenji.sx>
pkgbase=python-mccabe
pkgname=(python-mccabe python2-mccabe)
pkgver=0.6.1
pkgrel=5
pkgdesc="McCabe complexity checker for Python"
arch=('any')
url="https://github.com/flintwork/mccabe"
license=('custom:Expat')
makedepends=('python-pytest-runner' 'python2-pytest-runner')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/flintwork/mccabe/archive/$pkgver.tar.gz")
sha512sums=('1da239933f36c8b7c0f9f026822d673d0b207ac49e45027d77500001327964dd66cc7074be22311927176fc313174f4eb7908d0fc45da9fc4623bf1e237293b0')
prepare() {
cp -a mccabe-$pkgver{,-py2}
}
build() {
cd "$srcdir"/mccabe-$pkgver
python setup.py build
cd "$srcdir"/mccabe-$pkgver-py2
python2 setup.py build
}
check() {
cd "$srcdir"/mccabe-$pkgver
python setup.py test
cd "$srcdir"/mccabe-$pkgver-py2
python2 setup.py test
}
package_python-mccabe() {
depends=('python')
cd mccabe-$pkgver
python setup.py install --root="$pkgdir" --prefix=/usr --skip-build --optimize=1
install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
package_python2-mccabe() {
depends=('python2')
cd mccabe-$pkgver-py2
python2 setup.py install --root="$pkgdir" --prefix=/usr --skip-build --optimize=1
install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
# vim:set ts=2 sw=2 et:
|