PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: Johannes Wienke <languitar@semipol.de>

pkgname='python2-rsb-stable-git'
pkgver=0.16.0.95f99c4
_branch=0.16
pkgrel=1
pkgdesc='Robotics Service Bus Python implementation'
arch=(any)
url='https://projects.cor-lab.org/projects/rsb'
license=('LGPL3')
depends=('python2' 'python2-protobuf')
makedepends=('git' 'python2-setuptools' 'rsb-proto-stable-git' 'python2-nose' 'python2-pylint' 'python2-coverage' 'python2-spread')
optdepends=('spread-python2')
checkdepends=('spread-daemon' 'spread-python2' 'python2-nose' 'python2-pylint' 'python2-coverage')
source=("python2-rsb::git+https://code.cor-lab.org/git/rsb.git.python#branch=${_branch}")
md5sums=('SKIP')
conflicts=('python2-rsb')
provides=('python2-rsb')

pkgver() {
    cd "${srcdir}/python2-rsb"
    printf "%s" "$(git describe --long | sed 's/release-//;s/\([^-]*-\)g/\1/;s/-/./g')"
}

prepare() {
    cd "${srcdir}/python2-rsb"
    cat << EOF >> setup.cfg
[proto]
protocolroot=/usr/share/rsbprotocol${_branch}
EOF
}

build() {
    cd "${srcdir}/python2-rsb"
    python2 setup.py bdist_egg
}

check() {
    cd "${srcdir}/python2-rsb"
    python2 setup.py nosetests
}

package() {
    cd "${srcdir}/python2-rsb"
    python2 setup.py install --root="${pkgdir}/" --optimize=1
}