blob: 9de12c983b0374da8ebfa23824ad102d9e3861b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: 0x9fff00 <0x9fff00+git@protonmail.ch>
# Contributor: Florian Pritz <bluewind@xinu.at>
_name=schema
pkgname="python2-$_name"
pkgver=0.7.1
pkgrel=1
pkgdesc='Python module to validate and convert data structures.'
arch=('any')
url="https://github.com/keleshev/$_name"
depends=('python2' 'python2-contextlib2')
makedepends=('python2-setuptools')
checkdepends=('python2-mock' 'python2-pytest')
license=('MIT')
source=("https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz")
sha256sums=('c9dc8f4624e287c7d1435f8fd758f6a0aabbb7eff442db9192cd46f0e2b6d959')
build() {
cd "$_name-$pkgver"
python2 setup.py build
}
check() {
cd "$_name-$pkgver"
python2 setup.py test
}
package() {
cd "$_name-$pkgver"
python2 setup.py install --root="$pkgdir/" --optimize=1 --skip-build
install -D -m644 LICENSE-MIT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|