blob: 80bc9a053adcfca23b6adc3d0c8ff9833f611ca4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Andy Weidenbaum <archbaum@gmail.com>
pkgname=python2-snakebite
pkgver=2.7.0
pkgrel=1
pkgdesc="Pure Python HDFS client"
arch=('any')
depends=('python2'
'python2-argparse'
'python2-krbv'
'python2-protobuf'
'python2-sasl')
makedepends=('python2-setuptools')
url="https://github.com/spotify/snakebite"
license=('Apache')
options=(!emptydirs)
source=(https://pypi.python.org/packages/source/s/${pkgname#python2-}/${pkgname#python2-}-$pkgver.tar.gz)
md5sums=('5c95baa672fbe82fb2ddf4b6909c96fd')
sha256sums=('95c9fa0a477acf7431dbdfcc03d648500925617ae2a72d103dc7f944cdc8a81f')
provides=('python2-snakebite' 'snakebite')
conflicts=('snakebite')
build() {
cd "$srcdir/${pkgname#python2-}-$pkgver"
msg2 'Building...'
python2 setup.py build
}
package() {
cd "$srcdir/${pkgname#python2-}-$pkgver"
msg2 'Installing...'
python2 setup.py install --root="$pkgdir" --optimize=1
msg2 'Fixing LICENSE placement...'
install -dm 755 "$pkgdir/usr/share/licenses/$pkgname"
mv "$pkgdir/usr/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
msg2 'Fixing bash-completion placement...'
install -dm 755 "$pkgdir/usr/share/bash-completion/completions"
mv "$pkgdir/usr/etc/bash_completion.d/snakebite-completion.bash" \
"$pkgdir/usr/share/bash-completion/completions/snakebite"
rm -rf "$pkgdir/usr/etc"
}
|