summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 399a406afade0c2944f186e8362cb6afe77b54d8 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# Maintainer: Muflone http://www.muflone.com/contacts/english/

pkgbase=python2-x2go
pkgname=(python-x2go python2-x2go python-x2go-docs)
_pkgbase=python-x2go
pkgver=0.6.1.3
pkgrel=1
pkgdesc="Python module providing X2Go client API"
url="http://www.x2go.org/"
arch=('any')
license=('AGPL')
makedepends=('python-setuptools' 'python2-setuptools' 'epydoc'
             'python2-paramiko' 'python2-xlib' 'python2-gevent')
source=("http://code.x2go.org/releases/source/${_pkgbase}/${_pkgbase}-${pkgver}.tar.gz")
sha256sums=('08b951b434ba3b0e232fc5d01ab07c4b1d9c0e8d16af9722f78f52dd271a09f8')

prepare() {
  rm -rf "python2-x2go-${pkgver}"
  cp -r "${_pkgbase}-${pkgver}" "python2-x2go-${pkgver}"
  cp -r "${_pkgbase}-${pkgver}" "python-x2go-docs-${pkgver}"
}

build() {
  cd "${_pkgbase}-${pkgver}"
  python setup.py build

  cd "${srcdir}/python2-x2go-${pkgver}"
  python2 setup.py build
}

package_python-x2go() {
  pkgdesc="Python 3.x module providing X2Go client API"
  depends=('python-gevent' 'python-paramiko' 'python-requests'
           'python-simplejson' 'python-xlib' 'nxproxy')
  cd "${pkgname}-${pkgver}"
  python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
}

package_python2-x2go() {
  pkgdesc="Python 2.x module providing X2Go client API"
  depends=('python2-gevent' 'python2-paramiko' 'python2-requests'
           'python2-simplejson' 'python2-xlib' 'nxproxy')
  cd "${pkgname}-${pkgver}"
  python2 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
}

package_python-x2go-docs() {
  pkgdesc="Python module providing X2Go client API (docs package)"
  cd "${pkgname}-${pkgver}"
  install -m 755 -d "${pkgdir}/usr/share/doc/${pkgname}"
  epydoc --name "Python X2Go" --url http://www.x2go.org --no-private \
    --html --quiet --output "${pkgdir}/usr/share/doc/${pkgname}" x2go/
}