summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 2b9597f0211e7c942acdbd54fd92ddab800b7fa1 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
# Maintainer: Yen Chi Hsuan <yan12125 at gmail>
# Maintainer: Eric Berquist <eric DOT berquist AT gmail DOT com>
# Contributor: Rodolphe Breard <packages@what.tf>
# Contributor: Christopher Arndt <chris@chrisarndt.de>

pkgname=python33
pkgver=3.3.7
pkgrel=1
_pybasever=3.3
_pymajver=3
pkgdesc="Major release 3.3 of the Python high-level programming language"
arch=('i686' 'x86_64')
license=('custom')
url="https://www.python.org/"
depends=('expat' 'bzip2' 'gdbm' 'openssl-1.0' 'libffi' 'zlib')
makedepends=('tk' 'sqlite' 'valgrind' 'bluez-libs' 'mpdecimal')
optdepends=('mpdecimal: for decimal'
            'sqlite'
            'tk: for tkinter'
            'xz'
            'net-tools: arp, ifconfig and netstat are used in the uuid module')
checkdepends=('net-tools')
options=('!makeflags')
source=(https://www.python.org/ftp/python/${pkgver/rc*/}/Python-${pkgver}.tar.xz
        python-3.3-ssl-nosslv3.patch)
sha256sums=('85f60c327501c36bc18c33370c14d472801e6af2f901dafbba056f61685429fe'
            'd54bc0ac72218b37c1c2f7a8f03f904a06c2270518a5f3b9e27e54578fe1fb04')

prepare() {
  cd "${srcdir}/Python-${pkgver}"

  patch -Np1 -i ${srcdir}/python-3.3-ssl-nosslv3.patch

  # FS#23997
  sed -i -e "s|^#.* /usr/local/bin/python|#!/usr/bin/python|" Lib/cgi.py

  # Ensure that we are using the system copy of various libraries (expat, zlib and libffi),
  # rather than copies shipped in the tarball
  rm -rf Modules/expat
  rm -rf Modules/zlib
  rm -rf Modules/_ctypes/{darwin,libffi}*
  rm -rf Modules/_decimal/libmpdec
}

build() {
  cd "${srcdir}/Python-${pkgver}"

  export CPPFLAGS="-I/usr/include/openssl-1.0"
  export LDFLAGS="-L/usr/lib/openssl-1.0"
  ./configure --prefix=/usr \
              --enable-shared \
              --with-threads \
              --with-computed-gotos \
              --enable-ipv6 \
              --with-system-expat \
              --with-dbmliborder=gdbm:ndbm \
              --with-system-ffi \
              --with-system-libmpdec \
              --enable-loadable-sqlite-extensions

  make
}

check() {
  cd "${srcdir}/Python-${pkgver}"

  # make test
  LD_LIBRARY_PATH="${srcdir}/Python-${pkgver}":${LD_LIBRARY_PATH} \
                 "${srcdir}/Python-${pkgver}/python" -m test.regrtest -x \
                 test_distutils \
                 test_faulthandler \
                 test_ftplib \
                 test_ssl
}

package() {
  cd "${srcdir}/Python-${pkgver}"
  # altinstall: /usr/bin/pythonX.Y but not /usr/bin/python or /usr/bin/pythonX
  make DESTDIR="${pkgdir}" altinstall maninstall

  # Avoid conflicts with the main 'python' package.
  rm "${pkgdir}/usr/lib/libpython${_pymajver}.so"
  rm "${pkgdir}/usr/share/man/man1/python${_pymajver}.1"

  # fix FS#22552
  ln -sf ../../libpython${_pybasever}m.so \
    "${pkgdir}/usr/lib/python${_pybasever}/config-${_pybasever}m/libpython${_pybasever}m.so"

  # fix pycairo build
  ln -sf python${_pybasever}m-config "${pkgdir}/usr/bin/python${_pybasever}-config"

  # clean-up reference to build directory
  sed -i "s|$srcdir/Python-${pkgver}:||" "$pkgdir/usr/lib/python${_pybasever}/config-${_pybasever}m/Makefile"

  # license
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}