PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: moetayuko <loli at yuko dot moe>
# Contributor: lpt <aur AT lucapetrucci DOT net>
pkgname="qdiskinfo-git"
_pkgname="qdiskinfo"
pkgver=0.4.r8.gdb93fb1
pkgrel=1
pkgdesc="CrystalDiskInfo alternative for Linux"
url="https://github.com/edisionnano/QDiskInfo"
license=("GPL-3.0-only")
source=(
	"$_pkgname::git+$url.git"
)
sha256sums=(
	"SKIP"
)
arch=("x86_64")
depends=(
	"qt6-base"
	"qt6-declarative"
	"qt6-svg"
	"smartmontools"
	"polkit"
	"hicolor-icon-theme"
)
makedepends=(
	"cmake"
	"git"
	"qt6-tools"
)

conflicts=("$_pkgname")
provides=("$_pkgname")

pkgver() {
	cd "$_pkgname"
	git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build () {
	cd "$_pkgname"
	cmake \
		-DCMAKE_BUILD_TYPE=None \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DENABLE_TRANSLATIONS=ON \
		-DQT_VERSION_MAJOR=6 \
		-G"Unix Makefiles" \
		-Bbuilddir \
		-S.
	cmake --build builddir
}

package () {
	cd "$_pkgname"
	DESTDIR="$pkgdir" cmake --build builddir --target install
	install -Dm0644 "dist/QDiskInfo.png" "$pkgdir/usr/share/icons/hicolor/48x48/apps/QDiskInfo.png"
}