blob: cf644291d9f6d7ab431ce2f22f4ae6b9d6184410 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
|
# Maintainer: Christopher D. Degawa <ccom@randomderp.com>
# Contributor: haxibami <contact at haxibami dot net>
pkgname=qdrant-git
_pkgname=qdrant
pkgver=1.18.0+r5933+gfd6746ea9
pkgrel=1
pkgdesc="Vector Database and Vector Search Engine for AI"
backup=('etc/qdrant/config.yaml')
arch=('x86_64')
url="https://github.com/qdrant/qdrant"
license=('Apache')
depends=(
'gcc-libs'
'glibc'
'jemalloc'
'libunwind'
'lz4'
'shaderc'
'xz'
'zstd'
)
makedepends=(
'cargo'
'cmake'
'curl'
'git'
'mold'
'pkgconf'
'protobuf'
'python'
'rust-bindgen'
'unzip'
)
checkdepends=('cargo-nextest')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=(
git+https://github.com/qdrant/qdrant.git
0001-set-full-path-in-config.patch
qdrant.service
sysusers.conf
tmpfiles.d
)
sha256sums=('SKIP'
'6c40c64c69a72c44a4d01462887c8246f3459d29c8c3cc77108743d1b6a7b380'
'505b121c76184ec1a18db7a9f6fc3c4019c0f7a46db21d32c5816ed5a043e714'
'79493543ef27e8aad87e0241c1e2f4e964915e7b2f8aa08b17305ca1cfdc8d9e'
'e6560fbe2767e95b6f022acfee0b4b00d7b0fef84bc29d71f80849c935c77eea')
export RUSTUP_TOOLCHAIN=stable
# Use mold linker for faster linking
export RUSTFLAGS="${RUSTFLAGS:+${RUSTFLAGS} }-C link-arg=-fuse-ld=mold"
export CARGO_TARGET_DIR=target
pkgver() {
cd "${srcdir}/${_pkgname}"
_version=$(git describe --tags --abbrev=0 | tr - .)
_commits=$(git rev-list --count HEAD)
_short_commit_hash=$(git rev-parse --short=9 HEAD)
echo "${_version#'v'}+r${_commits}+g${_short_commit_hash}"
}
prepare() {
cd "${srcdir}/${_pkgname}"
# Replace -march with specific flags for better compatibility with the default makepkg.conf
sed -i 's/flag("-march=haswell");/flags(["-msse", "-mavx2"]);/' lib/quantization/build.rs
# Apply custom patches
patch -p1 -i "${srcdir}/0001-set-full-path-in-config.patch"
# Fetch Rust dependencies
cargo fetch --locked --target $(rustc --print host-tuple)
# Fetch prebuilt web UI from https://github.com/qdrant/qdrant-web-ui
[[ -d "static" ]] || ./tools/sync-web-ui.sh
}
build() {
cd "${srcdir}/${_pkgname}"
export JEMALLOC_OVERRIDE=/usr/lib/libjemalloc.so
export ZSTD_SYS_USE_PKG_CONFIG=1
export SHADERC_LIB_DIR=/usr/lib/
export AWS_LC_SYS_NO_JITTER_ENTROPY=1 # Work around jitterentropy complaining about -O{1,2,3} flags https://github.com/aws/aws-lc-rs/issues/1097
cargo build --release --frozen --features=gpu,stacktrace --bin qdrant
}
check() {
cd "${srcdir}/${_pkgname}"
cargo nextest run --profile ci --frozen --features=gpu,stacktrace
}
package() {
cd "${srcdir}/${_pkgname}"
install -Dm755 "target/release/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
install -dm755 "${pkgdir}/usr/share/qdrant"
cp -a "static" "${pkgdir}/usr/share/qdrant/"
install -Dm644 "config/config.yaml" "${pkgdir}/etc/qdrant/config.yaml"
install -Dm644 "${srcdir}/${_pkgname}.service" "$pkgdir/usr/lib/systemd/system/${_pkgname}.service"
install -Dm644 "${srcdir}/sysusers.conf" "$pkgdir/usr/lib/sysusers.d/${_pkgname}.conf"
install -Dm644 "${srcdir}/tmpfiles.d" "$pkgdir/usr/lib/tmpfiles.d/${_pkgname}.conf"
install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}
|