PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

# Maintainer: Lucas Saavedra Vaz <lucas.vaz at espressif dot com>
# Maintainer: Christian Heusel <christian at heusel dot eu>
pkgname="qemu-esp-xtensa-git"
_gitname="qemu"
pkgver=r117398.febae182e1
pkgrel=1
pkgdesc="Espressif's fork of QEMU with support for ESP32 xtensa boards. Git version."
arch=("x86_64")
url="https://github.com/espressif/qemu"
license=("GPL-2.0-or-later")
depends=(
  "dtc"
  "gcc-libs"
  "glib2"
  "glibc"
  "gnutls"
  "libbpf"
  "libgcrypt"
  "libseccomp"
  "libslirp"
  "pixman"
  "systemd-libs"
)
makedepends=(
  "git"
  "meson"
  "ninja"
  "pkgconf"
  "python"
  "python-setuptools"
)
provides=("qemu-esp-xtensa")
conflicts=("qemu-esp-xtensa")
options=("!buildflags" "!lto")
source=("qemu::git+https://github.com/espressif/qemu.git#branch=esp-develop")
sha256sums=("SKIP")

pkgver() {
  cd "$srcdir/${_gitname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "$srcdir/${_gitname}"
  ./configure \
            --target-list=xtensa-softmmu \
            --prefix=/opt/${pkgname} \
            --enable-gcrypt \
            --enable-slirp \
            --enable-debug \
            --disable-docs \
            --disable-werror \
            --disable-strip \
            --disable-user \
            --disable-capstone \
            --disable-vnc \
            --disable-sdl \
            --disable-gtk
  ninja -C build
}

package() {
  cd "$srcdir/${_gitname}"
  meson install -C build --destdir "$pkgdir"
  install -d "${pkgdir}/usr/bin"
  ln -s "/opt/${pkgname}/bin/qemu-system-xtensa" "${pkgdir}/usr/bin/qemu-esp-xtensa"
}