blob: a66d9cb7ddbf2550b4879f1bb556e09ef8c9bb46 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Maintainer: Stephan Springer <buzo+arch@Lini.de>
# Contributor: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Bruno Pagani <archange@archlinux.org>
# Contributor: Doug Newgard <scimmia at archlinux dot org>
# Contributor: XavierCLL <xavier.corredor.llano (a) gmail.com>
# Contributor: SaultDon <sault.don gmail>
# Contributor: Lantald < lantald at gmx.com >
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: dibblethewrecker dibblethewrecker.at.jiwe.dot.org
# Contributor: Gerardo Exequiel Pozzi <vmlinuz386@yahoo.com.ar>
# Contributor: Eric Forgeot < http://esclinux.tk >
_pkgname=qgis
pkgname="$_pkgname"-ltr
pkgver=3.28.11
pkgrel=1
pkgdesc='Geographic Information System (GIS); Long Term Release'
arch=(x86_64)
url='https://qgis.org/'
license=(GPL)
depends=(ocl-icd proj geos gdal expat spatialindex qwt libzip sqlite3 protobuf
zlib exiv2 postgresql-libs libspatialite zstd pdal
qt5-base qt5-svg qt5-serialport qt5-location qt5-3d qt5-declarative
qscintilla-qt5 qtkeychain-qt5 qca-qt5 gsl python-pyqt5 python-qscintilla-qt5
hdf5 netcdf libxml2) # laz-perf
makedepends=(cmake ninja opencl-clhpp fcgi qt5-tools sip pyqt-builder)
optdepends=('fcgi: Map server'
'gpsbabel: GPS Tools plugin')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=("https://download.qgis.org/downloads/$_pkgname-$pkgver.tar.bz2"
protobuf-23.patch
exiv2-0.28.patch)
sha256sums=('c5eb703893c7f98de051c45d677c4a34b40f986db51782a4930ddefad4e193b4'
'ac6c96e88346c1cec739b1e628afb02aef1895c0d09213269bad75b1a8cee617'
'b8f7181211263866829531d239e07ab7400d18b9afde70a8ced23f602dfb5c2f')
# curl https://download.qgis.org/downloads/qgis-latest-ltr.tar.bz2.sha256
prepare () {
cd "$_pkgname-$pkgver"
patch -p1 -i ../protobuf-23.patch
patch -p1 -i ../exiv2-0.28.patch
}
build() {
cmake -G Ninja -B build -S "$_pkgname-$pkgver" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DWITH_3D=TRUE \
-DWITH_QUICK=TRUE \
-DWITH_SERVER=TRUE \
-DWITH_CUSTOM_WIDGETS=TRUE \
-DBINDINGS_GLOBAL_INSTALL=TRUE \
-DQGIS_MANUAL_SUBDIR=share/man \
-DWITH_QTWEBKIT=FALSE \
-DWITH_QWTPOLAR=TRUE \
-DQWTPOLAR_LIBRARY=/usr/lib/libqwt.so \
-DQWTPOLAR_INCLUDE_DIR=/usr/include/qwt \
-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DQWT_POLAR_VERSION=0x060200" \
-DWITH_INTERNAL_QWTPOLAR=FALSE \
-DWITH_PDAL=TRUE \
-DHAS_KDE_QT5_PDF_TRANSFORM_FIX=TRUE \
-DHAS_KDE_QT5_SMALL_CAPS_FIX=TRUE \
-DHAS_KDE_QT5_FONT_STRETCH_FIX=TRUE
# https://github.com/qgis/QGIS/issues/48374
#-DWITH_INTERNAL_LAZPERF=FALSE \
# https://github.com/qgis/QGIS/issues/35440
#-DWITH_PY_COMPILE=TRUE \
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
install -Dm644 $_pkgname-$pkgver/rpm/sources/qgis-mime.xml "$pkgdir/usr/share/mime/packages/qgis.xml"
}
|