blob: 30ace3f64e007fb60c9e0c0d3c0efb819f080dec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Patrizio Bekerle <patrizio at bekerle dot com>
pkgname=qownnotes
pkgver=23.11.3
tag="952a3684e9840995673545b1509e7b1f286faadc"
pkgrel=1
pkgdesc="Plain-text file markdown note taking with Nextcloud/ownCloud integration"
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url='https://www.qownnotes.org/'
license=('GPL2')
groups=('qownnotes')
depends=('qt5-base' 'qt5-svg' 'qt5-declarative' 'openssl' 'qt5-websockets' 'qt5-x11extras' 'aspell')
makedepends=('qt5-tools')
source=("https://github.com/pbek/QOwnNotes/releases/download/v${pkgver}/qownnotes-${pkgver}.tar.xz")
sha256sums=('ef89cb613323a336c32c16d833af0972ec136579a01216193d7ca6e2222fb650')
prepare() {
cd "${pkgname}-${pkgver}"
echo "#define RELEASE \"AUR\"" > release.h
}
build() {
cd "${pkgname}-${pkgver}"
qmake QMAKE_CFLAGS_RELEASE="${CFLAGS}" QMAKE_CXXFLAGS_RELEASE="${CXXFLAGS}" QMAKE_LFLAGS_RELEASE="${LDFLAGS}"
make
}
package() {
cd "${pkgname}-${pkgver}"
# install application
install -D -m755 QOwnNotes "${pkgdir}/usr/bin/QOwnNotes"
# install visuals
install -D -m644 PBE.QOwnNotes.desktop "${pkgdir}/usr/share/applications/PBE.QOwnNotes.desktop"
for format in {16x16,24x24,32x32,48x48,64x64,96x96,128x128,256x256,512x512}; do
install -D -m644 "images/icons/${format}/apps/QOwnNotes.png" "${pkgdir}/usr/share/icons/hicolor/$format/apps/QOwnNotes.png"
done
install -D -m644 "images/icons/scalable/apps/QOwnNotes.svg" "${pkgdir}/usr/share/icons/hicolor/scalable/apps/QOwnNotes.svg"
# install languages
install -d "${pkgdir}/usr/share/qt5/translations/"
install -D -m644 languages/*.qm "${pkgdir}/usr/share/qt5/translations/"
}
|