blob: 519ba52477e6dc40e9a87bbd3b4d6eb0c68a502e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Patrizio Bekerle <patrizio at bekerle dot com>
pkgname=qownnotes
pkgver=21.11.4
tag="a15de696e72258f79919e3ad7c84f5930fff15e2"
pkgrel=1
pkgdesc="Plain-text file markdown note taking with Nextcloud/ownCloud integration"
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url='https://www.qownnotes.org/'
license=('GPL2')
groups=('qownnotes')
depends=('qt5-base' 'qt5-svg' 'qt5-declarative' 'openssl' 'qt5-xmlpatterns' 'qt5-websockets' 'qt5-x11extras' 'aspell')
makedepends=('qt5-tools')
source=("https://download.tuxfamily.org/${pkgname}/src/${pkgname}-${pkgver}.tar.xz")
sha256sums=('3eb025873160cecd4fa35ae5079c150d4aa5dd3152fd58c5e216b592af43e8dc')
prepare() {
cd "${pkgname}-${pkgver}"
echo "#define RELEASE \"AUR\"" > release.h
}
build() {
cd "${pkgname}-${pkgver}"
qmake QMAKE_CFLAGS_RELEASE="${CFLAGS}" QMAKE_CXXFLAGS_RELEASE="${CXXFLAGS}" QMAKE_LFLAGS_RELEASE="${LDFLAGS}"
make
}
package() {
cd "${pkgname}-${pkgver}"
# install application
install -D -m755 QOwnNotes "${pkgdir}/usr/bin/QOwnNotes"
# install visuals
install -D -m644 PBE.QOwnNotes.desktop "${pkgdir}/usr/share/applications/PBE.QOwnNotes.desktop"
for format in {16x16,24x24,32x32,48x48,64x64,96x96,128x128,256x256,512x512}; do
install -D -m644 "images/icons/${format}/apps/QOwnNotes.png" "${pkgdir}/usr/share/icons/hicolor/$format/apps/QOwnNotes.png"
done
install -D -m644 "images/icons/scalable/apps/QOwnNotes.svg" "${pkgdir}/usr/share/icons/hicolor/scalable/apps/QOwnNotes.svg"
# install languages
install -d "${pkgdir}/usr/share/qt5/translations/"
install -D -m644 languages/*.qm "${pkgdir}/usr/share/qt5/translations/"
}
|