summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e66547c50409ec6af3cd1fc073a6366aa584d413 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
# Maintainer: Treyfane Dingo <echo ZGluZ28rYXVyQGZ1cmNvbS5vcmcK | base64 -d>

_pkgname=QPrompt-Teleprompter
pkgname=qprompt-git
pkgver=2.0.0.rflatpak.0.gef9e038
pkgrel=1
pkgdesc="Teleprompter software for video creators (git version)"
arch=('x86_64')
url="https://qprompt.app/"
license=('GPL-3.0-only')
options=(!lto)

depends=(
  hicolor-icon-theme
  qt6-base
  qt6-declarative
  kcoreaddons
  kirigami
)

optdepends=(
  'qt6-wayland: Wayland platform support'
)

makedepends=(
  git
  cmake
  ninja
  extra-cmake-modules
  qt6-shadertools
  qt6-tools
  kirigami
)

provides=('qprompt')
conflicts=('qprompt')

source=("git+https://github.com/Cuperino/QPrompt-Teleprompter.git")
b2sums=('SKIP')

pkgver() {
    cd "${srcdir}/${_pkgname}"
    git describe --long --tags \
        | sed 's/^v//; s/-/.r/; s/-/./g'
}

prepare() {
  cd "$srcdir/$_pkgname"
  git submodule update --init --recursive
}

build() {
  cd "$srcdir/$_pkgname"
  cmake -GNinja \
        -Bbuild \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_C_FLAGS="${CFLAGS} -fPIC" \
        -DCMAKE_CXX_FLAGS="${CXXFLAGS} -fPIC" \
        -DCMAKE_EXE_LINKER_FLAGS="${LDFLAGS}"
  ninja -C build
}

package() {
  cd "$srcdir/$_pkgname"
  DESTDIR="$pkgdir" ninja -C build install
}