blob: d89f41758abfc2bb14b2664569bbfa4cbe8c38b6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: w568w <w568w at outlook dot com>
_pkgname=qq-wayland-clipboard
pkgname=$_pkgname-git
pkgver=0.1.0.r3.ga918398
pkgrel=1
pkgdesc='Clipboard compatibility wrapper for Linux QQ on Wayland'
arch=('x86_64' 'aarch64')
url='https://github.com/w568w/qq-wayland-clipboard'
license=('GPL-3.0-or-later')
depends=('glibc' 'libgcc' 'linuxqq' 'xorg-server-xvfb')
makedepends=('cargo' 'git')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+$url.git"
'wrapped-qq.desktop')
b2sums=('SKIP'
'd13abe15a958b75b53373db4dd3cf6c3686126cb8faa92d562225c55b346a35daea617075655dfc71a2066320fa8a3b52e65880387abe732f93773da2812538e')
pkgver() {
cd "$_pkgname"
local version
version=$(sed -n 's/^version = "\([^"]*\)"/\1/p' Cargo.toml | head -n1)
printf '%s.r%s.g%s' "$version" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
prepare() {
cd "$_pkgname"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$_pkgname"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
check() {
cd "$_pkgname"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo test --frozen --all-features
}
package() {
cd "$_pkgname"
install -Dm755 "target/release/$_pkgname" "$pkgdir/usr/bin/$_pkgname"
install -Dm644 "$srcdir/wrapped-qq.desktop" "$pkgdir/usr/share/applications/wrapped-qq.desktop"
}
|