blob: 349fccb8ca72585b45e6cfbb7c24431850786f6c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Michael Lass <bevan@bi-co.net>
# This PKGBUILD is maintained on github:
# https://github.com/michaellass/AUR
pkgname=qt-dab
pkgver=6.1
pkgrel=2
_prefix=qt-dab- # name of tarball and contents change from release to release
_tagname=$pkgver # tag names may differ from the application version
_major=${pkgver::1}
_pkgver=${_tagname//\//-}
_fullname=${pkgname}-${_major}
_fullname_s=${pkgname}-s${_major}
_binary=${pkgname}-${pkgver}
pkgdesc="Software DAB decoder for use with various SDR devices (formerly dab-maxi)"
arch=(x86_64)
url="https://www.sdr-j.tk/"
license=('GPL2')
depends=(faad2 fftw hicolor-icon-theme libsamplerate libsndfile portaudio qwt)
optdepends=('airspy: Support for Airspy'
'hackrf: Support for HackRF'
'limesuite: Support for LimeSDR'
'libad9361: Support for Pluto'
'rtl-sdr: Support for RTL-SDR'
'libsdrplay: Support for SDRplay')
source=("https://github.com/JvanKatwijk/${pkgname}/archive/refs/tags/${_prefix}${_tagname}.tar.gz"
"0001-Fix-compilation.patch")
sha256sums=('c29d7ef891364114c1ee47ab396e7e4ea75cd9e9077a27878ed51683cceb7793'
'88315e5e3bee137deb768e2cede03bb33987255ec30f7ea2ce3e567bda90c046')
prepare() {
cd "${_prefix}${pkgname}-${_pkgver}"
# The program is officially called Qt-DAB.
sed -i 's/Qt_DAB/Qt-DAB/g' ${_fullname_s}/${_fullname}.desktop
# Fix compilation
patch -p1 < "${srcdir}"/0001-Fix-compilation.patch
}
build() {
mkdir -p build; cd build
cmake \
-Wno-dev \
-DRTL_TCP=ON \
-DAIRSPY=ON \
-DLIMESDR=ON \
-DHACKRF=ON \
-DPLUTO=ON \
-DRTLSDR_LINUX=ON \
-DCMAKE_INSTALL_PREFIX=/usr \
../${_prefix}${pkgname}-${_pkgver}/${_fullname_s}
make
}
package() {
install -Dm 755 build/${_binary} "${pkgdir}"/usr/bin/${_fullname}
install -Dm 644 ${_prefix}${pkgname}-${_pkgver}/${_fullname_s}/${_fullname}.desktop "${pkgdir}"/usr/share/applications/${_fullname}.desktop
install -Dm 644 ${_prefix}${pkgname}-${_pkgver}/${_fullname_s}/${_fullname}.png "${pkgdir}"/usr/share/icons/hicolor/256x256/apps/${_fullname}.png
if [ $_major -gt 4 ]; then
install -Dm 644 ${_prefix}${pkgname}-${_pkgver}/docs/manual-${_major}.pdf "${pkgdir}"/usr/share/doc/${pkgname}/manual.pdf
else
install -Dm 644 ${_prefix}${pkgname}-${_pkgver}/qt-dab.pdf "${pkgdir}"/usr/share/doc/${pkgname}/manual.pdf
fi
}
|