blob: 8566b63b93e1374297f49e2ff0a78fe60cdcfdcd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Michael Lass <bevan@bi-co.net>
# This PKGBUILD is maintained on github:
# https://github.com/michaellass/AUR
pkgname=qt-dab
pkgver=4.4.2
_prefix= # name of tarball and contents change from release to release
_pkgver=4.4.2 # official versioning not necessarily compatible with pacman
_binary=${pkgname}-${_pkgver}
pkgrel=1
pkgdesc="Software DAB decoder for use with various SDR devices"
arch=(x86_64)
url="https://www.sdr-j.tk/"
license=('GPL2')
depends=(faad2 fftw hicolor-icon-theme libsamplerate libsndfile portaudio qwt)
optdepends=('airspy: Support for Airspy'
'hackrf: Support for HackRF'
'limesuite: Support for LimeSDR'
'libad9361: Support for Pluto'
'rtl-sdr: Support for RTL-SDR'
'libsdrplay: Support for SDRplay')
source=("https://github.com/JvanKatwijk/${pkgname}/archive/refs/tags/${_prefix}${_pkgver}.tar.gz")
sha256sums=('a19413f4d2d1adb30169462744c6b2f4eec357ac26c563688f147a73396d552b')
prepare() {
cd "${_prefix}${pkgname}-${_pkgver}"
# The program is officially called Qt-DAB.
sed -i 's/Qt_DAB/Qt-DAB/g' dab-maxi/${pkgname}.desktop
}
build() {
mkdir -p build-maxi; cd build-maxi
cmake \
-Wno-dev \
-DTRY_EPG=ON \
-DRTLSDR=ON \
-DRTL_TCP=ON \
-DAIRSPY=ON \
-DSDRPLAY_V3=ON \
-DLIMESDR=ON \
-DHACKRF=ON \
-DPLUTO=ON \
-DCMAKE_INSTALL_PREFIX=/usr \
../${_prefix}${pkgname}-${_pkgver}/dab-maxi
make
}
package() {
install -Dm 755 build-maxi/${_binary} "${pkgdir}"/usr/bin/${pkgname}
install -Dm 644 ${_prefix}${pkgname}-${_pkgver}/dab-maxi/${pkgname}.desktop "${pkgdir}"/usr/share/applications/${pkgname}.desktop
install -Dm 644 ${_prefix}${pkgname}-${_pkgver}/dab-maxi/${pkgname}.png "${pkgdir}"/usr/share/icons/hicolor/256x256/apps/${pkgname}.png
install -Dm 644 ${_prefix}${pkgname}-${_pkgver}/docs/manual.pdf "${pkgdir}"/usr/share/doc/${pkgname}/manual.pdf
}
|